1.1.2 Aantal contractuele FTE personeel in loondienst (PIL) zonder zorgfunctie op 1 januari

Concepten

• Arbeidsovereenkomst
• Contractomvang
• Contractomvangwaarde
• Functie in organisatie-rol
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• heeft deel
• heeft meeteenheid
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

Instanties

• FTE (36 uur per week)

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: NZA Wmg 1.1.2
2# Parameters:
3# Ontologie: versie 3.0
4# Aantal contractuele FTE personeel in loondienst (PIL) met een zorgfunctie op 1 januari
5
6PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX onz-g: <http://purl.org/ozo/onz-g#>
9PREFIX onz-org: <http://purl.org/ozo/onz-org#>
10PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
11
12SELECT 
13    (SUM(?fte) AS ?Teller)
14    ("Niet van toepassing" AS ?Noemer)
15    (?Teller AS ?Indicator_FTE36)
16{
17    {
18        SELECT 
19            ?overeenkomst_afspraak
20        {
21            BIND("2024-01-01"^^xsd:date AS ?peildatum)
22            ?overeenkomst 
23                a onz-pers:ArbeidsOvereenkomst ; # personeel in loondienst
24                onz-pers:heeftOpdrachtnemer ?persoon ;
25                onz-g:hasPart ?overeenkomst_afspraak .
26            ?overeenkomst_afspraak
27                a onz-pers:WerkOvereenkomstAfspraak ;
28                onz-g:startDatum ?start_afspraak .
29            OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
30            FILTER(?start_afspraak <= ?peildatum && ((?eind_afspraak >= ?peildatum) || (!BOUND(?eind_afspraak)))) # geldig op peildatum
31
32            ?overeenkomst_afspraak
33                onz-g:isAbout/a ?function_class .
34            ?function_class rdfs:subClassOf onz-g:OccupationalPositionRole .
35            BIND(IF(?function_class = onz-pers:ZorgverlenerFunctie, 1, 0) AS ?zorgverlener) # ?zorgverlener = 1 als afspraak over zorgverlenerfunctie gaat
36        }
37        GROUP BY ?overeenkomst_afspraak
38        HAVING (MAX(?zorgverlener) = 0) # neem max van ?zorgverlener omdat er dubbele regels voor kunnen komen (OccupationalPostionRole EN ZorgverlenerFunctie)
39                                        # filter zodat alleen niet-zorgverleners overblijven
40    }
41    ?overeenkomst_afspraak onz-g:hasPart ?omvang . # haal omvang van alle geldige afspraken op
42    ?omvang 
43        a onz-pers:ContractOmvang ;
44        onz-g:isAbout ?omvang_waarde .
45    ?omvang_waarde
46        a onz-pers:ContractOmvangWaarde ;
47        onz-g:hasDataValue ?omvang_waarde_getal ;
48        onz-g:hasUnitOfMeasure ?omvang_waarde_eenheid .
49    ?omvang_waarde_eenheid onz-g:hasDataValue ?eenheid_factor .
50    BIND(IF(?omvang_waarde_eenheid = onz-pers:fte_36, ?omvang_waarde_getal, ?omvang_waarde_getal / 36 * ?eenheid_factor) AS ?fte) # omrekenen naar fte_36
51}
52